Gambas: Html: Wikibrowser2 Form1.class

PUBLIC sZurueck AS String[]
PUBLIC sVor AS String[]

PUBLIC SUB Form_Open()
  sZurueck = NEW String[]
  sVor = NEW String[]
  
  TextBox1.Text = System.Home &/ "wiki/Gambas"

  Button1.Text = "Schließen"
  Button2.Text = "Zurück"
  Button3.Text = "Vor"
  Button2.Enabled = FALSE
  Button3.Enabled = FALSE
  
  sZurueck.Add(TextBox1.Text)
  txtLink_Activate

  ME.Border = Window.Resizable
  ME.W = 800
  ME.H = 600
  ME.Center
  ME.Text = "Wiki Browser V 2.0"
END

PUBLIC SUB Form_Resize()
  Button1.Move( ME.W - 125, 0, 125, 32 )
  Button2.Move( 0, 0, 125, 32 )
  Button3.Move( 125, 0, 125, 32 )
  Textbox1.Move( 0, Button1.H, ME.W, 32 )
  Label1.Move( 0, ME.H - 24, ME.W, 24 )
  WebBrowser1.Move( 0, TextBox1.H + Button1.H, ME.W, ME.H - TextBox1.H - Label1.H - Button1.H )
END

PUBLIC SUB WebBrowser1_Change()
  TextBox1.Text = LAST.Path
END

PUBLIC SUB WebBrowser1_Click()
  TextBox1.Text = LAST.Link
  
  'Seite für das Zurückgehen sichern
  sZurueck.Add(LAST.Link)
  IF sZurueck.Length > 1 THEN Button2.Enabled = TRUE

  'Speicher für das Vorwärtsgehen löschen
  sVor.Clear
  Button3.Enabled = FALSE
END

PUBLIC SUB WebBrowser1_Link()
  Label1.Text = LAST.Link
END

PUBLIC SUB txtLink_Activate()
   WebBrowser1.Path = Trim(TextBox1.Text)
END

PUBLIC SUB Button1_Click()
  ME.Close
END

PUBLIC SUB Button2_Click()
  'Rückwärts gehen

  'Link der aktuellen Seite für das Vorwärtsgehen sichern
  sVor.Add(sZurueck[sZurueck.Length - 1])
  Button3.Enabled = TRUE

  'Link der aktuellen Seite entfernen
  sZurueck.Remove(sZurueck.Length - 1)
  IF sZurueck.Length = 1 THEN Button2.Enabled = FALSE

  'Link der vorherigen Seite übernehmen
  WebBrowser1.Path = Trim(sZurueck[sZurueck.Length - 1])
END

PUBLIC SUB Button3_Click()
  'wieder Vorwärts gehen

  'Link der aktuellen Seite für das Rückwärtsgehen sichern
  sZurueck.Add(sVor[sVor.Length - 1])
  IF sZurueck.Length > 1 THEN Button2.Enabled = TRUE

  'Link zur nächsten Seite übernehmen
  WebBrowser1.Path = Trim(sVor[sVor.Length - 1])

  'Link der aktuellen Seite entfernen
  sVor.Remove(sVor.Length - 1)
  IF sVor.Length = 0 THEN Button3.Enabled = FALSE
END