Google Sheets-Kochbuch: Datenvalidierung

Aus Wikibooks


Mit der Datenvalidierung (Data Validation) können Sie sicherstellen, dass nur bestimmte, von Ihnen zugelassene Werte in Zellen eingetragen werden. Außerdem erzeugen Sie mit der Datenvalidierung Auswahllisten, also fancy DropDown-Listen.

Die Datenvalidierung rufen Sie über das Menü auf: Daten->Datenvalidierung.

Menü für die Datenvalidierung in Google Sheets
Menü für die Datenvalidierung in Google Sheets


  • Zellenbereich:
    • Der geschützte Bereich, in dem eine Fehleingabe verhindert werden soll.
Kriterien für die Datenvalidierung
  • Kriterien:
    • Welche Werte in dem Bereich erlaubt sein sollen.
  • Drop-Down-Liste in Zelle anzeigen
    • Erzeugt eine Auswahlliste in der Zelle.
    • Diese Option ist nur für Liste aus einem Bereich und für Elementliste verfügbar.
  • Bei ungültigen Daten:
    • Warnung zeigen - Lässt die Eingabe zu, zeigt aber eine Meldung an.
    • Eingabe ablehnen - Lässt keine fehlerhaften Eingaben zu.
  • Darstellung:
    • Validierungshilfetext anzeigen: Hier können Sie einen Text eingeben, der als Eingabehilfe dient. Dieser wird allerdings nicht auf allen Geräten angezeigt.


Liste aus einem Bereich[Bearbeiten]

Datenvalidierung - Kriterium - Liste aus einem Bereich
Datenvalidierung - Kriterium - Liste aus einem Bereich


Aus den Werten im Bereich - hier $A$3:$A$20 - wird automatisch die Auswahlliste erzeugt. Dabei werden doppelte Werte verworfen, die Liste wird nicht sortiert.

Wenn Sie eine sortierte Liste wünschen, sortieren Sie die Liste in der Tabelle selbst.

Sie können hier auch benannte Bereiche verwenden:

  • =NameDesBereiches

Elementliste[Bearbeiten]

Die Elementliste ist dafür vorgesehen, dass Sie durch Komma getrennte Elemente für die Validierung verwenden.

  • Abteilung 1, Abteilung 2, Abteilung 3
    • Zeichenketten müssen nicht in Hochkommata eingefasst werden.
  • =A1+B1,=A1*B1
    • Sie können hier sogar Formeln eingeben, und dann aus den Formeln auswählen.
    • Sie erhalten aber dann immer folgende Fehlermeldung: "Ungültig: Die Eingabe muss ein Eintrag auf der angegebenen Liste sein"
    • Die Formel funktioniert, ich bin aber nicht sicher, ob das so vorgesehen ist (es wäre schön, wenn das so wäre, dann könnte man verschiedene Auswertungen in einem Drop-Down-Feld bereitstellen).

Zahl[Bearbeiten]

Hier können Sie zwei Zahlen einstellen, und dann zwischen verschiedenen Optionen wählen:

  • zwischen (den beiden Zahlen)
  • nicht zwischen
  • kleiner als
  • usw...

Die beiden Zahlen können Sie auch als absolute Zellbezüge angeben, so dass sich die Grenzen des Bereiches abhängig von den Werten in den Zellen ändern.

Über diese Datenvalidierung können Sie auch die Eingabe eines beliebigen Zahlwertes erzwingen, der auch beliebig formatiert sein darf (z.B. mit Tausendertrennpunkt).

  • Validierung Zahl größer als =-1,79769313486231*10^308
    • Ich vermute, das ist für praktisch alle Zwecke ausreichend, es handelt sich um die kleinste Zahl, die in Google Sheets darstellbar ist.

Text[Bearbeiten]

Folgende Optionen haben Sie für die Überprüfung von Text:

  • enthält
  • enthält nicht
  • gleich
  • ist gültige E-Mail
  • ist eine gültige URL

Die Textvergleiche sind nicht case sensitive, Groß- und Kleinschreibung spielt also keine Rolle. Die Überprüfung auf eine gültige E-Mail Adresse oder eine gültige URL sind sehr praktisch, dann muss man dazu keine - möglicherweise etwas unbequemen - regulären Ausdrücke verwenden.

Datum[Bearbeiten]

Folgende Optionen haben Sie für die Überprüfung von Daten:

  • ist ein gültiges Datum
  • gleich
  • vor
  • nach
  • zwischen
  • usw...

Benutzerdefinierte Formel ist[Bearbeiten]

Das Ergebnis der Formel muss wahr sein, kann also auch einen Zahlwert außer 0 annehmen. Dabei verwendet man typischerweise den Inhalt der Zelle selbst und überprüft ihn auf die Einhaltung der richtigen Kriterien. Insbesondere lassen sich hier reguläre Ausdrücke verwenden (z.B. mit REGEXMATCH), oder Sequenzen erstellen (mit SEQUENCE).

Die folgenden Beispiele beziehen sich auf die Überprüfung der Werte in der Zelle A1.

  • =ISODD(A1)
    • Ist die Zahl ungerade?
  • =ISEVEN(A1)
    • Ist die Zahl gerade?
  • =REGEXMATCH(A1;"B.*e")
    • Fängt die Eingabe mit einem großen B an, und hört mit einem kleinen e auf?
    • Matched also "Biene", "Blume", "Blüte", "Bär war müde", ...

Schöne Spielereien gehen wieder mit SEQUENCE:

  • =MATCH(A1;SEQUENCE(1;1000;4;4);0)
    • Ist die Zahl in der 4er-Reihe bis 4.000 enthalten?
    • Dieses konkrete Beispiel ließe sich natürlich auch über die Teilbarkeit durch 4 darstellen.
  • =MATCH(A1;INDEX(CHAR(SEQUENCE(26;1;65)));0)
    • Die Sequenz erzeugt die Großbuchstaben A-Z.
    • MATCH sucht auch nach Kleinbuchstaben.
    • Es werden also einzelne Buchstaben A-Z bzw. a-z zugelassen.
    • Auf diese Weise lassen sich auch andere Buchstabenlisten erzeugen.

Erzwingung eindeutiger Werte[Bearbeiten]

Es gibt wie immer viele Möglichkeiten.

  • =COUNTIF(A$2:A2;A3)=0
    • Wählen Sie die Zelle A3 aus.
    • Aktivieren Sie die Datenvalidierung für die Zelle A3.
    • Geben Sie die obige Formel ein.
    • Kopieren Sie die Datenvalidierung in alle Zellen der Spalte, in denen Sie sie benötigen. Durch die relativen Zellbezüge ändert sich der Range des Bereiches.


  • =IF(COUNTUNIQUE(A:A)/COUNT(A:A)=1;TRUE;FALSE)
    • Diese Datenvalidierung können Sie auf die ganze Spalte anwenden.
    • Es werden nur Zahlen zugelassen, da COUNT nur nummerische Werte zählt.
    • Es werden die eindeutigen Werte im Bereich gezählt, hier in Spalte A.
    • Teilt man durch die Anzahl, ist das Ergebnis nur 1, wenn jeder Wert eindeutig ist, also nur einmal vorkommt.
    • Möchten Sie eine Spaltenüberschrift in der Spalte, beginnen Sie mit dem Bereich unterhalb der Spaltenüberschrift (hier in A1):
      • =IF(COUNTUNIQUE(A$2:A)/COUNT(A$2:A)=1;TRUE;FALSE)


  • =IF(COUNTUNIQUE(A:A)/COUNTA(A:A)=1;TRUE;FALSE)
    • Diese Datenvalidierung können Sie auf die ganze Spalte anwenden.
    • Hier werden auch Zeichenketten zugelassen, da mit COUNTA auch Zeichenketten gezählt werden.

Kästchen[Bearbeiten]

Optionen für Datenvalidierung Kästchen
Optionen für Datenvalidierung Kästchen

Die Kästchen-Option erzeugt Checkboxen. Im Gegensatz zu den anderen Optionen wird die Datenvalidierung gelöscht, wenn der Inhalt der Zelle gelöscht wird. Sie können die Kästchen also genausogut über Einfügen->Kästchen einfügen.

Beim Einfügen über die Datenvalidierung haben Sie allerdings noch die zusätzliche Möglichkeit, einen benutzerdefinierten Zellenwert zu verwenden. Dann können Sie diesen Wert abfragen, und nicht nur TRUE oder FALSE.



Die Beispiele auf dieser Seite wurden getestet: 04/2022