TI-Basic: Programme und Tutorials: Quersumme

Hoch zu "Programme und Tutorials"

Erstellt von:	Peter Riedel
Schwierigkeitsgrad:	fortgeschritten
Modell:	Voyage 200

Quersumme

 Quersumme

Bei folgenden Funktionen und Programmen ist es nicht nötig die Ziffernanzahl $k$ der natürlichen Zahl $n$ als zweites Argument zu übergeben, sondern wird intern mithilfe der Funktion $\operatorname {numdigit} (n,1)$ in Abhängigkeit von $n$ automatisch berechnet. $k$ wird im Quelltext also durch $\operatorname {numdigit} (n,1)$ ersetzt. Allerdings kann das häufige Aufrufen von Funktionen bei Zahlen mit vielen Stellen die Geschwindigkeit der Ausführung deutlich verringern. Daher sollte man bei rechenintensiven Anwendungen $k$ mitübergeben, auch wenn das weniger komfortabel ist als nur ein Argument übergeben zu müssen.

$\operatorname {numdigit} (n,i)={\begin{cases}\operatorname {numdigit} (n,i+1),&{\mbox{wenn }}n\operatorname {mod} 10^{i}<n\\i,&{\mbox{wenn }}n\operatorname {mod} 10^{i}=n\end{cases}}$

:numdigit(n,i)
:Func
:While 10^i≤n
:©While mod(n,10^i)<n
:  i+1→i
:EndWhile
:Return i
:EndFunc

:numdigit(n,i)
:Func
:If 10^i≤n Then
:©If mod(n,10^i)<n Then
:  Return numdigit(n,i+1)
:Else
:  Return i
:EndIf
:EndFunc

Linksassoziativ

$k$ Ziffern der natürlichen Zahl $n$ werden von links nach rechts ziffernweise addiert, sodass man die Quersumme $\operatorname {qs} (n,k)$ von $n$ erhält.

$\operatorname {qs} (n,k)=\sum _{i=0}^{k-1}\;{\frac {n\;\operatorname {mod} \;10^{k-i}\;-\;n\;\operatorname {mod} \;10^{k-i-1}}{10^{k-i-1}}}\;\Leftrightarrow \;\operatorname {qs} (n,k)=\sum _{i=1}^{k}\;{\frac {n\;\operatorname {mod} \;10^{k-i+1}\;-\;n\;\operatorname {mod} \;10^{k-i}}{10^{k-i}}}$

$n\in \mathbb {N} ,\;k\in \mathbb {N} \setminus \{0\}$

Funktion

:qs(n)
:Func
:If n<0 or mod(n,1)≠0
:  Return undef
:Return Σ((mod(n,10^(numdigit(n,1)-i))-mod(n,10^(numdigit(n,1)-i-1)))/10^(numdigit(n,1)-i-1),i,0,numdigit(n,1)-1)
:©Return Σ((mod(n,10^(numdigit(n,1)-i+1))-mod(n,10^(numdigit(n,1)-i)))/10^(numdigit(n,1)-i),i,1,numdigit(n,1))
:EndFunc

Programm

:qs(n)
:Prgm
:ClrIO
:If n<0 or mod(n,1)≠0 Then
:  Disp "Fehler: n ∈ N = {0,1,2,...,∞}"
:  Return
:EndIf
:numdigit(n,1)→i
:string(n)→n
:0→q
:0→k
:While k<i
:  k+1→k
:  expr(mid(n,k,1))→j
:  q+j→q
:EndWhile
:string(q)→q
:Disp "Quersumme: "&q
:EndPrgm

Rechtsassoziativ

$k$ Ziffern der natürlichen Zahl $n$ werden von rechts nach links ziffernweise addiert, sodass man die Quersumme $\operatorname {qs} (n,k)$ von $n$ erhält.

$\operatorname {qs} (n,k)=\sum _{i=0}^{k-1}\;{\frac {n\;\operatorname {mod} \;10^{i+1}\;-\;n\;\operatorname {mod} \;10^{i}}{10^{i}}}\;\Leftrightarrow \;\operatorname {qs} (n,k)=\sum _{i=1}^{k}\;{\frac {n\;\operatorname {mod} \;10^{i}\;-\;n\;\operatorname {mod} \;10^{i-1}}{10^{i-1}}}$

$n\in \mathbb {N} ,\;k\in \mathbb {N} \setminus \{0\}$

Funktion

:qs(n)
:Func
:If n<0 or mod(n,1)≠0
:  Return undef
:Return Σ((mod(n,10^(i+1))-mod(n,10^i))/10^i,i,0,numdigit(n,1)-1)
:©Return Σ((mod(n,10^i)-mod(n,10^(i-1)))/10^(i-1),i,1,numdigit(n,1))
:EndFunc

Programm

:qs(n)
:Prgm
:ClrIO
:If n<0 or mod(n,1)≠0 Then
:  Disp "Fehler: n ∈ N = {0,1,2,...,∞}"
:  Return
:EndIf
:numdigit(n,1)→i
:string(n)→n
:0→q
:While i>0
:  expr(mid(n,i,1))→j
:  q+j→q
:  i-1→i
:EndWhile
:string(q)→q
:Disp "Quersumme: "&q
:EndPrgm

Iterative Quersumme

 Iterative Quersumme

$\operatorname {itqs} (n,z)={\begin{cases}0,&{\mbox{wenn }}n=0\\z,&{\mbox{wenn }}n\;\operatorname {mod} \;z=0\ {\text{und}}\ n\neq 0\\n\;\operatorname {mod} \;z,&{\mbox{wenn }}n\;\operatorname {mod} \;z\neq 0\end{cases}}$

:itqs(n,z)
:Func
:If mod(n,z)≠0 Then
:  Return mod(n,z)
:ElseIf mod(n,z)=0 and n≠0 Then
:  Return z
:Else
:  Return 0
:EndIf
:EndFunc

Rekursion

$\operatorname {itqs} (n,k)={\begin{cases}\operatorname {qs} (n,k),&{\mbox{wenn }}\operatorname {qs} (n,k)<10\\\operatorname {itqs} (\operatorname {qs} (n,k),\operatorname {numdigit(qs} (n,k),1)),&{\mbox{wenn }}\operatorname {qs} (n,k)\geq 10\end{cases}}$

$n\in \mathbb {N} ,\;k\in \mathbb {N} \setminus \{0\}$

Funktion

:itqs(n)
:Func
:If qs(n)≥10 Then
:  Return itqs(qs(n))
:Else
:  Return qs(n)
:EndIf
:EndFunc

Programm

:itqs(n)
:Prgm
:ClrIO
:If n<0 or mod(n,1)≠0 Then
:  Disp "Error: n ∈ N = {0,1,2,...,∞}"
:  Return
:EndIf
:0→k
:While n>9
:  num(n,1)→i
:  string(n)→n
:  0→q
:  While i>0
:    expr(mid(n,i,1))→j
:    q+j→q
:    i-1→i
:  EndWhile
:  k+1→k
:  q→n
:EndWhile
:string(n)→n
:string(k)→k
:Disp "additive digital root: "&n,"additive persistence: "&k
:EndPrgm

Alternierende Quersumme

 Alternierende Quersumme

Linksassoziativ

$k$ Ziffern der natürlichen Zahl $n$ werden von links nach rechts ziffernweise abwechselnd addiert und subtrahiert, sodass man die alternierende Quersumme $\operatorname {aqs} (n,k)$ von $n$ erhält.

$\operatorname {aqs} (n,k)=\sum _{i=0}^{k-1}\;{\frac {n\;\operatorname {mod} \;10^{k-i}\;-\;n\;\operatorname {mod} \;10^{k-i-1}}{10^{k-i-1}}}\;\cdot \;(-1)^{i}\;\Leftrightarrow \;\operatorname {aqs} (n,k)=\sum _{i=1}^{k}\;{\frac {n\;\operatorname {mod} \;10^{k-i+1}\;-\;n\;\operatorname {mod} \;10^{k-i}}{10^{k-i}}}\;\cdot \;(-1)^{i-1}$

$n\in \mathbb {N} ,\;k\in \mathbb {N} \setminus \{0\}$

Funktion

:aqs(n)
:Func
:If n<0 or mod(n,1)≠0
:  Return undef
:Return Σ((mod(n,10^(numdigit(n,1)-i))-mod(n,10^(numdigit(n,1)-i-1)))/10^(numdigit(n,1)-i-1)*(-1)^i,i,0,numdigit(n,1)-1)
:©Return Σ((mod(n,10^(numdigit(n,1)-i+1))-mod(n,10^(numdigit(n,1)-i)))/10^(numdigit(n,1)-i)*(-1)^(i-1),i,1,numdigit(n,1))
:EndFunc

Rechtsassoziativ

$k$ Ziffern der natürlichen Zahl $n$ werden von rechts nach links ziffernweise abwechselnd addiert und subtrahiert, sodass man die alternierende Quersumme $\operatorname {aqs} (n,k)$ von $n$ erhält.

$\operatorname {aqs} (n,k)=\sum _{i=0}^{k-1}\;{\frac {n\;\operatorname {mod} \;10^{i+1}\;-\;n\;\operatorname {mod} \;10^{i}}{10^{i}}}\;\cdot \;(-1)^{i}\;\Leftrightarrow \;\operatorname {aqs} (n,k)=\sum _{i=1}^{k}\;{\frac {n\;\operatorname {mod} \;10^{i}\;-\;n\;\operatorname {mod} \;10^{i-1}}{10^{i-1}}}\;\cdot \;(-1)^{i-1}$

$n\in \mathbb {N} ,\;k\in \mathbb {N} \setminus \{0\}$

Funktion

:aqs(n)
:Func
:If n<0 or mod(n,1)≠0
:  Return undef
:Return Σ((mod(n,10^(i+1))-mod(n,10^i))/10^i*(-1)^i,i,0,numdigit(n,1)-1)
:©Return Σ((mod(n,10^i)-mod(n,10^(i-1)))/10^(i-1)*(-1)^(i-1),i,1,numdigit(n,1))
:EndFunc

Nichtalternierende t-Quersumme

 Nichtalternierende t-Quersumme

Zahlenblöcke mit $t$ Ziffern der natürlichen Zahl $n$ mit $k$ Ziffern werden von rechts nach links blockweise addiert, sodass man die $t$-Quersumme $\operatorname {tqs} (n,k,t)$ von $n$ erhält.

$\operatorname {tqs} (n,k,t)=\sum _{i=0}^{\frac {k-1}{t}}\;{\frac {n\;\operatorname {mod} \;10^{i\cdot t+t}\;-\;n\;\operatorname {mod} \;10^{i\cdot t}}{10^{i\cdot t}}}$

Funktion

:tqs(n,t)
:Func
:If n<0 or mod(n,1)≠0 or t<1 or mod(t,1)≠0
:  Return undef
:Return Σ((mod(n,10^(i*t+t))-mod(n,10^(i*t)))/10^(i*t),i,0,(numdigit(n,1)-1)/t)
:©Return Σ((mod(n,10^(i*t))-mod(n,10^(i*t-t)))/10^(i*t-t),i,1,numdigit(n,1)/t+1)
:EndFunc

Alternierende t-Quersumme

 Nichtalternierende t-Quersumme

Zahlenblöcke mit $t$ Ziffern der natürlichen Zahl $n$ mit $k$ Ziffern werden von rechts nach links blockweise abwechselnd addiert und subtrahiert, sodass man die $t$-Quersumme $\operatorname {tqs} (n,k,t)$ von $n$ erhält.

$\operatorname {atqs} (n,k,t)=\sum _{i=0}^{\frac {k-1}{t}}\;{\frac {n\;\operatorname {mod} \;10^{i\cdot t+t}\;-\;n\;\operatorname {mod} \;10^{i\cdot t}}{10^{i\cdot t}}}\cdot (-1)^{i}$

Funktion

:atqs(n,t)
:Func
:If n<0 or mod(n,1)≠0 or t<1 or mod(t,1)≠0
:  Return undef
:Return Σ((mod(n,10^(i*t+t))-mod(n,10^(i*t)))/10^(i*t)*(-1)^i,i,0,(numdigit(n,1)-1)/t)
:©Return Σ((mod(n,10^(i*t))-mod(n,10^(i*t-t)))/10^(i*t-t)*(-1)^(i-1),i,1,numdigit(n,1)/t+1)
:EndFunc